Bob Faist’s Blog

I received an email asking how to access track information using a release title. Below is an example of how this is done.

use strict;
use WebService::MusicBrainz::Release;
use WebService::MusicBrainz::Track;

my $album = "Parachutes";

my $ws = WebService::MusicBrainz::Release->new();

# broad search based on album title
my $response = $ws->search({ TITLE => $album });

# get first match of the release
my $first_match = $response->release();

# now that we know MBID, lets ask for track details
my $release_search = $ws->search({ MBID => $first_match->id(),

                                   INC => 'tracks' });

# get first match with track details
my $release_search_first = $release_search->release();

print "Amazon ASIN : ", $release_search_first->asin(), "\n";

my $track_ws = WebService::MusicBrainz::Track->new();

# track number is not part of the web service data so let's create our own
my $track_num = 0;

foreach my $track (@{ $release_search_first->track_list()->tracks() }) {
    $track_num++;

    # query track data with artist details
    # artist at the release level could be "Various Artists",
    #   so we need to query each track for it's artist
    my $track_response = $track_ws->search({ MBID => $track->id(),

                                             INC => 'artist' });

    my $found_track = $track_response->track();

    print $track_num, ": ", $found_track->title(), " - ",

          $found_track->artist()->sort_name(), "\n";
}

Here is the output from this example:

Amazon ASIN : B00004U9MS
1: Don’t Panic – Coldplay
2: Shiver – Coldplay
3: Spies – Coldplay
4: Sparks – Coldplay
5: Yellow – Coldplay
6: Trouble – Coldplay
7: Parachutes – Coldplay
8: High Speed – Coldplay
9: We Never Change – Coldplay
10: Everything’s Not Lost / Life Is for Living – Coldplay